@echo off
    TITLE Quick copy from As400 physical file to PC text.
    cd \
    echo FROMPF.bat
    echo    Quick copy from As400 physical file to PC text.
    echo    .
    echo    Copia veloce da un file fisico As400 a un file txt su PC.
    echo    .
    echo    Claudio Neroni 28-04-2015 Creato.
    echo    .
rem      <...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....>
    echo    ATTENZIONE: l'estensione del presente file DEVE ESSERE ".bat".
    echo    Il nome del file AS400 viene ricavato dal nome del file PC.
    echo    Il nome della libreria del file As400 viene ricavato dall'estensione del file PC.
    echo    Il nome e l'estensione del file PC possono essere forniti trascinando l'icona del file PC 
    echo    sopra l'icona del presente ".bat".
    echo    .
    echo    Il nome del membro, se diverso dal nome del file, 
    echo       puo' essere fornito spezzando il nomefilepc in nomefileas400.nomemembroas400 
    echo    Se il nome del file pc e' nella forma "file.libreria",
    echo       viene copiato nel file pc il membro As400 omonimo del file.
    echo    Se il nome del file pc e' nella forma "file.membro.libreria",
    echo       viene copiato nel file pc il membro As400 "membro" del file.
    echo    .
    echo    I parametri di accesso all'As400
    echo    "ASSYSTEM", "MYUSER" e "MYPASSWORD" 
    echo    si possono cablare per chiarezza e semplicita' 
    echo    ma per impostarli e' consigliabile fare uso di un altro ".bat"
    echo    (ad esempio ACCESSO400.bat), contenente le specifiche di settaggio.
    echo    .
    set msg=Perche' funzioni, occorre trascinare il file scatenante sul presente bat!  
    @if .%1==. @echo ERRORE! && @echo %msg% && @pause && GOTO ENDPGM
rem Annota Parametri di accesso.
rem    set assystem=ASSYSTEM
rem    set myuser=MYUSER
rem    set mypassword=MYPASSWORD
rem Chiama batch alternativo alle precedenti specifiche di settaggio.
    call J:\ACCESSO400.bat
rem Imposta l'indirizzario di lavoro.
    set work=WORK
rem Imposta un nome di lavoro.
    set workname=FROMPF
rem Crea l'indirizzario di lavoro %WORK% sul disco di lavoro.
    md C:\%WORK%
rem Ricava in file il nome completo del file.
    set file=%1
rem Ricava in filename il nome del file senza percorso e senza estensione.
    set filename=%~n1
rem Compone il nome del work file che conterra' le istruzioni ftp da eseguire.
    set workftp=C:\%WORK%\%workname%.ftp
rem Ricava in fileextension il nome dell'estensione del file.
    set fileextension=%~x1
    set fileextension=%fileextension:~1,10%
rem Scrive le istruzioni da eseguire con ftp.
rem Utente.
    echo %myuser%>%WORKFTP%
rem Password.
    echo %mypassword%>>%WORKFTP%
rem Copia da file fisico As400 a file PC.
    echo get "%fileextension%/%filename%" %file%>>%WORKFTP%
rem Abbandona ftp.
    echo quit>>%WORKFTP%
rem Chiama ftp per eseguire le istruzioni scritte nel file.
    ftp -s:%WORKFTP% %assystem%
    pause Si ferma per permettere l'esame del log prima che si chiuda la finestra comandi.
rem Cancella transito.
    del %WORKFTP%