cd \
rem ATTENZIONE: l'estensione del presente file DEVE ESSERE ".bat".
rem Claudio Neroni 20-06-2008 Creato.
rem Copia un file da PC a IFS di AS400.
rem Il nome completo del file PC puo' essere fornito come parametro o digitato alla richiesta del programma
rem ma il modo migliore di passare il parametro e' trascinare l'icona del file PC sopra l'icona del presente ".bat". 
rem Se il nome del file non contiene il percorso, viene cercato nell'indirizzario di lavoro %d%\IFSWORK
rem Crea l'indirizzario ifs, se manca, all'interno di /home.
rem Sistema, Utente, Password e Indirizzario destinatario sono cablati per tenere tutto in un unico ".bat".

rem Annota Nome dell'As400, Utente e Password.
   set adr=PUB1.RZKH.DE
   set usr=NERONI
   set pwd=pppppppppp
rem Annota todir "Indirizzario IFS destinatario della copia"
   set todir=neroni

rem Assume come d "Disco di lavoro" quello in cui si trova il presente ".bat".
   set d=%~d0
rem Crea l'indirizzario di lavoro IFSWORK sul disco di lavoro
   md %d%\IFSWORK
rem Ricava in filen il nome e l'estensione del file scritto nel primo parametro ricevuto.
   set filen=%~nx1
rem Ricava in file il nome completo del file scritto nel primo parametro ricevuto.
   set file=%1
rem Se il file non e' valorizzato, salta alla sua acquisizione.
   if %file%.==. goto file1
rem Salta a nome file acquisito.
   goto file2
rem Label acquisizione.
   :file1
rem Acquisisce il nome del file da digitazione estemporanea.
   set /p file=
rem Se il nome del file e' ancora vuoto, abbandona.
   if %file%.==. goto fine
rem Label File acquisito.
   :file2
rem Ricava dal nome completo del file il nome.estensione nella variabile "filen".
   echo set filen=%%~nx1>%d%\IFSWORK\IFSWORK2.bat
   call %d%\IFSWORK\IFSWORK2.bat %file%
rem Scrive le istruzioni da eseguire con ftp.
rem Utente.
   echo %usr%>%d%\IFSWORK\IFSWORK.txt
rem Password.
   echo %pwd%>>%d%\IFSWORK\IFSWORK.txt
rem Crea indirizzario ricevente in IFS.
   echo mkdir "/home/%todir%">>%d%\IFSWORK\IFSWORK.txt
rem Imposta indirizzario locale.
   echo lcd %d%\IFSWORK>>%d%\IFSWORK\IFSWORK.txt
rem Imposta indirizzario IFS.
   echo cd /home/%todir%>>%d%\IFSWORK\IFSWORK.txt
rem Copia il file dall'indirizzario locale o,comunque, dalla sua posizione all'indirizzario IFS.
   echo put %file% "%filen%">>%d%\IFSWORK\IFSWORK.txt
rem Abbandona ftp.
   echo quit>>%d%\IFSWORK\IFSWORK.txt
rem Chiama ftp per eseguire le istruzioni scritte nel file .
   ftp -s:%d%\IFSWORK\IFSWORK.txt %adr%
   del %d%\IFSWORK\IFSWORK.txt
   del %d%\IFSWORK\IFSWORK2.bat
rem Label fine.
   :fine
   pause Si ferma per permettere l'esame del log prima che si chiuda la finestra comandi.