@echo off
    TITLE Quick copy from As400 source member to PC text
    cd \
    echo FROMSOURCE.bat
    echo    Quick copy from As400 source member to PC text.
    echo    .
    echo    Copia veloce da un membro sorgente As400 a un file txt su PC.
    echo    .
    echo    Claudio Neroni 17-07-2008 Creato.
    echo    .
rem      <...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....>
    echo    ATTENZIONE: l'estensione del presente file DEVE ESSERE ".bat".
    echo    Il nome completo del file PC puo' essere fornito trascinando l'icona 
    echo    del file PC sopra l'icona del presente ".bat".
    echo    Il nome del file PC di tipo txt ricevente del contenuto del membro sorgente 
    echo    viene acquisito nel primo parametro di chiamata %%1 tramite trascinamento.
    echo    Membro sorgente e file PC sono omonimi tra loro.
    echo    Per poter usare la tecnica del trascinamento, quando  
    echo    non si abbia a disposizione una vecchia edizione del file da ottenere,
    echo    si puo' creare una vecchia edizione fasulla la' dove si vuole ottenere 
    echo    la nuova e poi trascinarla sul presente ".bat".
    echo    .
    echo    I parametri di accesso all'As400
    echo    "ASSYSTEM", "MYUSER" e "MYPASSWORD" 
    echo    si possono cablare per chiarezza e semplicita' 
    echo    ma per impostarli e' consigliabile fare uso di un altro ".bat"
    echo    (ad esempio ACCESSO400.bat), contenente le specifiche di settaggio.
    echo    .
    echo    Anche i parametri di personalizzazione della procedura
    echo    "FROMASFILE" e "FROMASLIBRARY" 
    echo    sono gestiti nello stesso file di settaggio.
    echo    .
    set msg=Perche' funzioni, occorre trascinare il file scatenante sul presente bat!  
    @if .%1==. @echo ERRORE! && @echo %msg% && @pause && GOTO ENDPGM
rem Annota Parametri di accesso.
rem    set assystem=ASSYSTEM
rem    set myuser=MYUSER
rem    set mypassword=MYPASSWORD
rem Imposta file e libreria che contengono il membro sorgente da scaricare su PC.
rem    set fromasfile=FROMASFILE
rem    set fromaslibrary=FROMASLIBRARY
rem Chiama batch alternativo alle precedenti specifiche di settaggio.
    call J:\ACCESSO400.bat
rem Imposta l'indirizzario di lavoro.
    set work=WORK
rem Imposta un nome di lavoro.
    set workname=FROMSOURCE
rem Crea l'indirizzario di lavoro sul disco di lavoro.
    md C:\%WORK%
rem Ricava in file il nome completo del file.
    set file=%1
rem Ricava in filename il nome del file senza percorso e senza estensione.
    set filename=%~n1
rem Compone il nome del work file che conterra' le istruzioni ftp da eseguire.
    set workftp=C:\%WORK%\%workname%.ftp
rem Scrive le istruzioni da eseguire con ftp.
rem Utente.
    echo %myuser%>%WORKFTP%
rem Password.
    echo %mypassword%>>%WORKFTP%
rem Copia da membro sorgente As400 a file PC.
    echo get "/qsys.lib/%fromaslibrary%.lib/%fromasfile%.file/%filename%.mbr" %file%>>%WORKFTP%
rem Abbandona ftp.
    echo quit>>%WORKFTP%
rem Chiama ftp per eseguire le istruzioni scritte nel file.
    ftp -s:%WORKFTP% %assystem%
    pause Si ferma per permettere l'esame del log prima che si chiuda la finestra comandi.
rem Cancella transito.
    del %WORKFTP%
:ENDPGM